first save

entities/road/do_spline.gd

@@ -0,0 +1,32 @@
+@tool
+extends Path3D
+class_name RoadPath
+@export_tool_button("update_control_points") var action = update_control_points
+
+func modulo_get_point_position(i):
+	return curve.get_point_position(posmod(i, curve.point_count))
+
+func update_control_points():
+	if curve.point_count < 2:
+		return
+	
+	#
+	## Start point: out control based on next point
+	#var dir = (curve.get_point_position(1) - curve.get_point_position(0)).normalized()
+	#var tangent_length = dir.length() / 3 
+	#
+	#curve.set_point_out(0, dir * tangent_length)
+	
+	# Intermediate points: in and out controls based on adjacent points
+	for i in range(0, curve.point_count):
+		var prev = modulo_get_point_position(i) - modulo_get_point_position(i - 1)
+		var next = modulo_get_point_position(i + 1) - modulo_get_point_position(i)
+		var prev_dir = prev.normalized()
+		var next_dir = next.normalized()
+		var tangent_length = next.length() / 3 
+		var tangent = (prev_dir + next_dir)
+		
+		tangent.y = 0
+		tangent = tangent.normalized()
+		curve.set_point_in(i, -tangent * tangent_length)
+		curve.set_point_out(i, tangent * tangent_length)

entities/road/do_spline.gd.uid

@@ -0,0 +1 @@
+uid://bdw7xdf1lc3ud

entities/road/road.gd

@@ -0,0 +1,118 @@
+@tool
+extends StaticBody3D
+class_name Road
+
+@export_tool_button("create_mesh") var action_generate = generate_mesh
+@export_tool_button("clear_all") var action_clear = clear_all
+
+@export var track : RoadPath
+@export var road_mesh_instance : MeshInstance3D
+@export var road_shape : CollisionShape3D
+@export var road_material : BaseMaterial3D
+@export var segment_length := 0.1
+@export var road_width : float = 1.5
+@export var road_thickness : float = 0.5
+
+var st_road = SurfaceTool.new()
+
+func clear_all():
+	st_road = SurfaceTool.new()
+	st_road.clear()
+	road_mesh_instance.mesh = null
+	if road_shape and road_shape.shape:
+		road_shape.shape = null
+
+func generate_mesh():
+	clear_all()
+	st_road.begin(Mesh.PRIMITIVE_TRIANGLES)
+	if road_material:
+		st_road.set_material(road_material)
+		
+	var curve := track.curve
+	var race_length = curve.get_baked_length()
+	var nb_of_point : int = race_length / segment_length
+
+	for i in range(nb_of_point):
+		var dist1 = float(i) * segment_length
+		var dist2 = float(i + 1) * segment_length
+
+		var t1 := curve.sample_baked_with_rotation(dist1, true)
+		var t2 := curve.sample_baked_with_rotation(dist2, true)
+
+		var fwd1 = t1.basis.z.normalized()
+		var fwd2 = t2.basis.z.normalized()
+
+		var right1 = t1.basis.x.normalized()
+		var right2 = t2.basis.x.normalized()
+		
+		var left1 = -right1
+		var left2 = -right2
+		
+		var up1 = t1.basis.y.normalized()
+		var up2 = t2.basis.y.normalized()
+
+		var p1 := t1.origin
+		if i == 0:
+			p1 += fwd1 * 0.05
+		var p2 := t2.origin
+
+		# Top vertices
+		var p1_right = p1 + right1 * road_width * 0.5
+		var p1_left = p1 - right1 * road_width * 0.5
+		var p2_right = p2 + right2 * road_width * 0.5
+		var p2_left = p2 - right2 * road_width * 0.5
+
+		# Bottom vertices
+		var p1_right_bottom = p1_right - up1 * road_thickness
+		var p1_left_bottom = p1_left - up1 * road_thickness
+		var p2_right_bottom = p2_right - up2 * road_thickness
+		var p2_left_bottom = p2_left - up2 * road_thickness
+
+		# Top face
+		create_rectangle(p1_right, p1_left, p2_left, p2_right, up1, up2, Vector2(0, dist1 / road_width), Vector2(1, dist2 / road_width))
+
+		# Bottom face (inverted normal)
+		create_rectangle(p1_left_bottom, p1_right_bottom, p2_right_bottom, p2_left_bottom, up1, up2, Vector2(1, dist1 / road_width), Vector2(0, dist2 / road_width))
+
+		# Right side face
+		create_rectangle(p1_right_bottom, p1_right, p2_right, p2_right_bottom, right1, right2, Vector2(dist1 / road_thickness, 0), Vector2(dist2 / road_thickness, 1))
+
+		# Left side face
+		create_rectangle(p1_left, p1_left_bottom, p2_left_bottom, p2_left, left1, left2, Vector2(dist1 / road_thickness, 0), Vector2(dist2 / road_thickness, 1))
+
+	var final_mesh = st_road.commit()
+	road_mesh_instance.mesh = final_mesh
+	
+	var shape = final_mesh.create_trimesh_shape()
+	road_shape.shape = shape
+
+func create_rectangle(
+	v1: Vector3, v2: Vector3, v3: Vector3, v4: Vector3,
+	normal1: Vector3, normal2: Vector3,
+	uv1: Vector2, uv2: Vector2
+):
+	# Triangle 1
+	st_road.set_uv(uv1)
+	st_road.set_normal(normal1)
+	st_road.add_vertex(v1)
+
+	st_road.set_uv(Vector2(uv1.x, uv2.y))
+	st_road.set_normal(normal1)
+	st_road.add_vertex(v2)
+
+	st_road.set_uv(uv2)
+	st_road.set_normal(normal2)
+	st_road.add_vertex(v3)
+
+	# Triangle 2
+	st_road.set_uv(uv2)
+	st_road.set_normal(normal2)
+	st_road.add_vertex(v3)
+
+	st_road.set_uv(Vector2(uv2.x, uv1.y))
+	st_road.set_normal(normal1)
+	st_road.add_vertex(v4)
+
+	st_road.set_uv(uv1)
+	st_road.set_normal(normal1)
+	st_road.add_vertex(v1)

entities/road/road.gd.uid

@@ -0,0 +1 @@
+uid://bgt66573ipmub

entities/road/road_path.tscn

@@ -0,0 +1,16 @@
+[gd_scene load_steps=3 format=3 uid="uid://cjk3phtyyiyty"]
+
+[ext_resource type="Script" uid="uid://bdw7xdf1lc3ud" path="res://entities/road/do_spline.gd" id="1_c4y0q"]
+
+[sub_resource type="Curve3D" id="Curve3D_p7e7j"]
+closed = true
+_data = {
+"points": PackedVector3Array(0.246495, 0, 4.21189, -0.246495, 0, -4.21189, 0, 0, 0, -4.24042, 0, 0.00829778, 4.24042, 0, -0.00829778, 10, 0, -7.75931, -4.21783, 0, -0.014848, 4.21783, 0, 0.014848, 20, 1.27448, 0, -4.24638, 0, 0.0109491, 4.24638, 0, -0.0109491, 30, 0, -7.64779, -2.44782, 0, -6.85357, 2.44782, 0, 6.85357, 40, 1.9489, 0, 12.6025, 0, -5.29505, -12.6025, 0, 5.29505, 35.1108, 0, 21.1888),
+"tilts": PackedFloat32Array(0, 0, 0, 0, 0, 0)
+}
+point_count = 6
+
+[node name="Track" type="Path3D"]
+transform = Transform3D(1, 0, 0, 0, 1, 0, 0, 0, 1, 0.00397015, 0, 0)
+curve = SubResource("Curve3D_p7e7j")
+script = ExtResource("1_c4y0q")